A solution in Nim language. Pretty straightforward code. Most logic is just parsing input + a bit of functional utils: allIt checks if all items in a list within limits to check if game is possible and mapIt collects red, green, blue cubes from each set of game.

https://codeberg.org/Archargelod/aoc23-nim/src/branch/master/day_02/solution.nim

import std/[strutils, strformat, sequtils]

type AOCSolution[T] = tuple[part1: T, part2: T]

type
  GameSet = object
    red, green, blue: int
  Game = object
    id: int
    sets: seq[GameSet]

const MaxSet = GameSet(red: 12, green: 13, blue: 14)

func parseGame(input: string): Game =
  result.id = input.split({':', ' '})[1].parseInt()
  let sets = input.split(": ")[1].split("; ").mapIt(it.split(", "))
  for gSet in sets:
    var gs = GameSet()
    for pair in gSet:
      let
        pair = pair.split()
        cCount = pair[0].parseInt
        cName = pair[1]

      case cName:
      of "red":
        gs.red = cCount
      of "green":
        gs.green = cCount
      of "blue":
        gs.blue = cCount

    result.sets.add gs

func isPossible(g: Game): bool =
  g.sets.allIt(
    it.red <= MaxSet.red and
    it.green <= MaxSet.green and
    it.blue <= MaxSet.blue
  )


func solve(lines: seq[string]): AOCSolution[int]=
  for line in lines:
    let game = line.parseGame()

    block p1:
      if game.isPossible():
        result.part1 += game.id

    block p2:
      let
        minRed = game.sets.mapIt(it.red).max()
        minGreen = game.sets.mapIt(it.green).max()
        minBlue = game.sets.mapIt(it.blue).max()

      result.part2 += minRed * minGreen * minBlue


when isMainModule:
  let input = readFile("./input.txt").strip()
  let (part1, part2) = solve(input.splitLines())

  echo &"Part 1: The sum of valid game IDs equals {part1}."
  echo &"Part 2: The sum of the sets' powers equals {part2}."